How to: Never have to save a replay again...

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::                                                                    
:: Script to automatically copy or move SC2Replay files from the      
:: Unsaved folder to the Multiplayer folder (or wherever you want).   
::                                                                    
:: NOTE: Set the "source" and "destination" paths for your account.   
::       Set "action" to "move" if you want to move the files, or     
::       "copy" to copy them.                                         
::                                                                    
:: Will not overwrite any existing files and names files uniquely     
:: based on the date and time they were created.                      
::                                                                    
:: NOTE! I doubt this will work properly on anything but standard US  
:: English locales because the date parser I wrote specifically for   
:: the standard US English date format.                               
::                                                                    
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

set source=C:\Users\USER\Documents\StarCraft II Beta\Accounts\12345\1-A1-1-12345\Replays\Unsaved
set destination=C:\Users\USER\Documents\StarCraft II Beta\Accounts\12345\1-A1-1-12345\Replays\Multiplayer
set action=move

REM Gets the list of files to copy from the source folder, doesn't actually copy yet
for /f "usebackq tokens=*" %%a in (`xcopy "%source%" "%destination%" /L /Y /I`) do (
        if exist "%%a" (
            REM Gets rid of number in parentheses after replay name
            if %%~xa==.SC2Replay (
                for /f "delims=( tokens=1" %%b in ("%%~na") do (
                    REM Gets rid of trailing space
                    set baseName=%%b##
                    set baseName=!baseName: ##=##!
                    set baseName=!baseName:##=!
                )
                REM Gets date/time modified.
                REM Standard US English Date/Time parser, tweak if you
                REM use a non-standard date/time format or locale.
                REM Converts from "Sun 7/11/2010 01:50 PM" to "20100711-1350"
                for /f "tokens=1-6 delims=/: " %%c in ("%%~ta") do (
                    set hour=%%f
                    set AMPM=%%h
                    if "!AMPM!"=="AM" (
                        if "!hour!"=="12" set hour=00
                    ) else (
                    if "!AMPM!"=="PM" (
                    if "!hour:~0,1!"=="0" set hour=!hour:~1,1!
                    if not "!hour!"=="12" set /A hour=!hour!+12
                    )
                    )
                    set modTime=%%e%%c%%d-!hour!%%g
                    set output=%destination%\!baseName! !modTime!.SC2Replay
                    
                    if not exist "!output!" (
                        if "%action%"=="copy" (
                            echo Copying "%%a" to "!output!"...
                            copy "%%a" "!output!" /Y
                        ) else (
                            echo Moving "%%a" to "!output!"...
                            move /Y "%%a" "!output!"
                        )
                    )
                )
            )
        )
    )
)
:: Uncomment next line to prompt you to hit a key before exiting so you can examine output
REM pause

1. Click the Start button on the taskbar.
   
2. Type "Task Scheduler" in the Search box and click the first result that says Task Scheduler.
   
3. Expand the Task Scheduler Library folder in the list pane on the left.
   
4. Right click the Task Scheduler Library folder and choose "New Folder". Give it a name like My Custom Tasks.
   
5. Right click your new folder and choose "Create Task" (not "Create Basic Task", we want a little more flexibility than what the basic wizard offers).
   
6. Enter a name like "SC2 Replay Backup" for the Name and a description if you want.
   
7. Click the Triggers tab.
   
8. Click New.
   
9. For "Begin the task", choose "At log on".
   
10. Select Specific user and it will only run when you are logged in.
    
11. Under Advanced Settings, check Repeat task every and choose "5 minutes" for the first box and a duration of "Indefinitely" for the second box.
    
12. Click OK.
    
13. Click the Actions tab.
    
14. Click New.
    
15. Type wscript.exe in the Program/script box.
    
16. In the Arguments box type the following, substituting your own paths to the script files you created earlier:
    

    "C:\path to\invisible.vbs" "C:\path to\sc2replays.bat"

    Include the quotes around each argument.
    
17. Click OK twice
    
18. Log out of your machine (or restart) and log back in.

1. Click the Start button on the task bar.
   
2. Click Run...
   
3. Type "control schedtasks" (minus quotes) in the box and click OK. This is a shortcut to the Scheduled Tasks applet.
   
4. Go to File-New-Scheduled Task. This bypasses the useless "Add Scheduled Task" wizard.
   
5. Give the new task a name like SC2 Replay Backup
   
6. Right click the new task and choose Properties
   
7. In the Run box enter the following, substituting your own paths to the script files you created earlier:
   

   wscript.exe "C:\path to\invisible.vbs" "C:\path to\sc2replays.bat"

   Include the quotes around each argument.
   
8. Check the "Run only if logged on" box.
   
9. Click the Schedule tab
   
10. Leave the Schedule Task box as "Daily". Adjust the Start time to a few minutes from now, or whenever you want the script to start the very first time. We'll set it up to run continuously so this doesn't matter too much.
    
11. Click the Advanced button.
    
12. Check the Repeat task box.
    
13. Change the interval to every 5 minutes, or as often as you like.
    
14. Change the duration box to 24 hours.
    
15. Click OK.
    
16. Click the Settings tab.
    
17. Uncheck "Stop the task if it runs for..."
    
18. Click OK.

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
::
:: Script to automatically copy or move SC2Replay files from the
:: Unsaved folder to the Multiplayer folder (or wherever you want).
::
:: NOTE: Set the "source" and "destination" paths for your account.
:: Set "action" to "move" if you want to move the files, or
:: "copy" to copy them.
::
:: Will not overwrite any existing files and names files uniquely
:: based on the date and time they were created.
::
:: NOTE! The date parser will work for most locales but not all.
::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

set source=C:\Users\USER\Documents\StarCraft II\Accounts\12345\1-A1-1-12345\Replays\Unsaved
set destination=C:\Users\USER\Documents\StarCraft II\Accounts\12345\1-A1-1-12345\Replays\Multiplayer
set action=move

REM Gets date/time format information from registry
FOR /F "tokens=3" %%A IN ('REG QUERY "HKEY_CURRENT_USER\Control Panel\International" /v iTime 2^>NUL') DO SET iTime=%%A
FOR /F "tokens=3" %%A IN ('REG QUERY "HKEY_CURRENT_USER\Control Panel\International" /v sDate 2^>NUL') DO SET sDate=%%A
FOR /F "tokens=3" %%A IN ('REG QUERY "HKEY_CURRENT_USER\Control Panel\International" /v sTime 2^>NUL') DO SET sTime=%%A
FOR /F "tokens=3" %%A IN ('REG QUERY "HKEY_CURRENT_USER\Control Panel\International" /v s1159 2^>NUL') DO SET s1159=%%A

REM Gets the list of files to copy from the source folder, doesn't actually copy yet
for /f "usebackq tokens=*" %%a in (`xcopy "%source%" "%destination%" /L /Y /I`) do (
  if exist "%%a" (
    REM Gets rid of number in parentheses after replay name
    if %%~xa==.SC2Replay (
      for /f "delims=0123456789( tokens=1" %%b in ("%%~na") do (
        REM Gets rid of trailing space
        set baseName=%%b##
        set baseName=!baseName: ##=##!
        set baseName=!baseName:##=!
      )
      REM Gets date/time modified.
      REM Universal Date/Time parser
      REM Works for most locales but not 100%
      
      for /f "tokens=1*" %%c in ("%%~ta") do (
        set modDate=%%c
        set modTime=%%d
      )
      
      call :Get_Date
      call :Get_Time

      REM Output time format string - feel free to adjust
      REM Note, destFolder gives a year-month folder structure for replay storage
      set destTime=!yy!-!mm!-!dd! !hh!!mn!
      set destFolder=!yy!-!mm!
      set datedest=%destination%\!destFolder!

      if not exist "!datedest!" %comspec% nul /cmd "!datedest!"
      
      REM I like the date first so files sort by date automatically
      set output=!datedest!\!destTime! !baseName!.SC2Replay
	  
      if not exist "!output!" (
        if "%action%"=="copy" (
          echo Copying "%%a" to "!output!"...
          copy "%%a" "!output!" /Y
        ) else (
          echo Moving "%%a" to "!output!"...
          move /Y "%%a" "!output!"
        )
      )
    )
  )
)
:: Uncomment next line to prompt you to hit a key before exiting so you can examine output
REM pause
goto :eof

:Get_Date
if "%modDate%A" LSS "A" (set toks=1-3) else (set toks=2-4)
for /f "usebackq skip=1 tokens=2-4 delims=(-)" %%a in (`echo:^|date`) do (
  for /f "usebackq tokens=%toks% delims=%sDate% " %%d in ('%modDate%') do (
    set %%a=%%d
    set %%b=%%e
    set %%c=%%f
    set toks=
  )
)
goto :eof

:Get_Time
if "%modTime%A" LSS "A" (set toks=3) else (set toks=1)
for /f "usebackq tokens=%toks% delims=%sTime% " %%a in ('%modTime%') do (set AMPM=%%a)
if "%modTime%A" LSS "A" (set toks=1-2) else (set toks=2-3)
for /f "usebackq tokens=%toks% delims=%sTime% " %%a in ('%modTime%') do (
  set hh=%%a
  set mn=%%b
  if "!AMPM!"=="AM" (
    set s1159=AM
    set iTime=0
  ) else (
    if "!AMPM!"=="PM" (
      set iTime=0
    )
  )
  if "!iTime!"=="0" (
    if "!AMPM!"=="%s1159%" (
      if "!hh!"=="12" set hh=00
    ) else (
      if "!hh:~0,1!"=="0" set hh=!hh:~1,1!
      if not "!hh!"=="12" set /A hh=!hh!+12
    )
  )
  set AMPM=
  set toks=
)
goto :eof